Türmod für den Mercedes O405N2, Einsteigen vorne, aussteigen hinten [Gelöst]

Anzahl der Beiträge : 1903 Anmeldedatum : 10.01.11

Hallo,

vorab: Ich habe so gut wie keine vom Scripten, versuche mir daher etwas herzuleiten.

Ich habe den O405 heruntergeladen und verusche mich gerade an folgendem:

Die Passagiere sollen nur vorne einsteigen und an den hinteren Türen beliebig aussteigen. Veränderte Punkte habe ich dazu bereits treffend in der passengercabin des Modells gesetzt.

Es stellt sich momentan aber folgendes Problem:

Die Fahrgäste laufen zu vordersten Tür und bleiben auch bei geöffnter Tür davor stehen. Erst wenn die dritte Tür geöffnet wird, steigen sie ein. Bleibt die vorderste Tür zu und man öffnet nur die dritte, steigen die Fahrgäste durch die geschlossene Tür ein.
Hier die Zeilen aus dem Orginalscript dergenutzen Door-Osc.

Spoiler:

Kann mir jemand erklären, was "0", "1" bzw "2" bedeutet?

Ich dachte bisher immer, dass "0" auf oder zu,
"1" auf,
"2" zu bedeutet.
Das scheint aber nicht der Fall zu sein.

Anzahl der Beiträge : 2837 Anmeldedatum : 09.02.10 Alter : 29 Ort : Koblenz

Sauter schrieb:: Ich dachte bisher immer, dass "0" auf oder zu,
"1" auf,
"2" zu bedeutet.
Das scheint aber nicht der Fall zu sein.

Wenn's nur darum geht:
Soweit ich weiß heißt "0" ganz geschlossen und "1" ganz geöffnet mit stufenlosem Übergang.

Anzahl der Beiträge : 1903 Anmeldedatum : 10.01.11

...ja dann darfst Du auch gerne zur Tat schreiten und das umkonfigurieren Wink

Anzahl der Beiträge : 2837 Anmeldedatum : 09.02.10 Alter : 29 Ort : Koblenz

Dafür musst du den Code nochmal anders bereitstellen, z.B. durch Screenshot, denn oben wurden alle Zeichen wie && oder = geschluckt Wink

EDIT: Vergiss alles. Ich bin zu blöd. Moment, ich denke nach.

EDIT 2:
Was ist damit?

Zitat :: {macro:Door_Frame}
(M.L.Door0_Calc)
(M.L.Door1_Calc)
(M.L.DoorAftCalc)
(M.L.Door2_Calc)
(M.L.Door3_Calc)

(L.L.door_0) 0.9 > (S.L.PAX_Entry1_Open)
(L.L.door_1) 0.9 > (S.L.PAX_Exit1_Open) (S.L.PAX_Entry0_Open)

Lass einfach mal die letzte Zeile weg. Ist ziemlich geraten, könnte aber das Problem sein.
BACKUP machen! Ich weiß nicht, wie OMSI reagiert Wink

Anzahl der Beiträge : 1903 Anmeldedatum : 10.01.11

Nun steigen die Fahrgäste nur ein, wenn die zweite Tür geöffnet wird.

Anzahl der Beiträge : 2837 Anmeldedatum : 09.02.10 Alter : 29 Ort : Koblenz

Ok, wie ist's damit?

Zitat :: {macro:Door_Frame}
(M.L.Door0_Calc)
(M.L.Door1_Calc)
(M.L.DoorAftCalc)
(M.L.Door2_Calc)
(M.L.Door3_Calc)

(L.L.door_0) 0.9 > (S.L.PAX_Entry0_Open)
(L.L.door_1) 0.9 > (S.L.PAX_Exit1_Open)

Die sollen ja nur vorne einsteigen und hinten nur aussteigen, oder? Sollte damit gehen, denke ich.

Anzahl der Beiträge : 1903 Anmeldedatum : 10.01.11

Das ist schon nicht schlecht.

Ein letztes Problem. Es stehen Fahrgäste an der hinteren (dritten) Tür und verlassen den Bus nicht, obwohl die Tür geöffnet ist.

Du siehst....das Ergebnis nähert sich...

Anzahl der Beiträge : 1476 Anmeldedatum : 21.02.11 Alter : 39 Ort : Hannover

Bin mal eben im Wettbüro!

zum Thema; wenn ihr das Script dafür fertig habt, könnt ihr das gerne bereitstellen, ich habe schon gelesen, dass andere selbiges Problem haben Smile

Anzahl der Beiträge : 1903 Anmeldedatum : 10.01.11

Ja ja Sedici.
Dann setz mal auf Jan. Der hat bisher alle meine OMSI Probleme in den Griff bekommen.

JAN
Ich habe Tür 3 analog zu Tür 2 gescriptet. Nun steigen Fahrgäste erst aus 2 aus, wenn 3 auch auf ist.
Herrlich, oder?
Ich versuche das mal hintereinander zu kleben, das 3 akzeptiert, das 1 und 2 aucvh zu sein dürfen.

L Ö S U N G
=======

Die Lösung wurde gefunden.

Zuerst geht ihr bitte in die passengercabin_D92 des MB o405N2 und ändert dort das Ein -und Aussteigeverhalten der Passgiere wie folgt:

Spoiler:

Anschliessend geht ihr in die doordar.osc Datei des MBo405N2 und ändert das Macro für die Tür auf folgende Werte:

Spoiler:

Fertig.

Anzahl der Beiträge : 2837 Anmeldedatum : 09.02.10 Alter : 29 Ort : Koblenz

Ups, Sauter, geht auf meine Kappe... die dritte Tür hab ich schlichtweg vergessen, sonst hätte meine Lösung auch schon funktioniert Wink

Naja, Hauptsache es klappt und du bist glücklich Cool

Anzahl der Beiträge : 285 Anmeldedatum : 18.07.09

danke für diesen Mod.
Das Problem ist jetzt nur, dass vorne einer Aussteigen will, das aber nicht tut, obwohl die türen offen sind.
Also scheint das mit dem Ausstieg vorne noch nicht gelöst..

Anzahl der Beiträge : 1903 Anmeldedatum : 10.01.11

Hi Mobiel. Genau das Problem hatte ich nun auch gerade nach einer ausgiebigen Testfahrt.

Ich werde mich nochmal ranmachen und entferne solange das "[Gelöst]" aus dem Thread.

DAS ALS LÖSUNG GEPOSTET SCRIOPT WURDE GEÄNDERT UND KANN VERWENDET WERDEN.

Anzahl der Beiträge : 285 Anmeldedatum : 18.07.09

wo ist denn der unterschied zum voherigen script?

Anzahl der Beiträge : 1903 Anmeldedatum : 10.01.11

Durch das Copy&Paste hat sich bei der passengercabin noch ein exit-Wert für die vordere Tür eingeschlichen. Diesen habe ich entfernt.

Anzahl der Beiträge : 285 Anmeldedatum : 18.07.09

ok. Danke

Anzahl der Beiträge : 153 Anmeldedatum : 19.02.11 Alter : 28 Ort : Bremerhaven

Hallo.

Der Mod funktioniert bei mir nicht richtig!
Die Fahrgäste steigen vorne erst ein, wenn die hintere Tür offen ist!
Edit: Habe mal wieder zu schnell gelesen, und die "door.osc" statt der "doordar.osc" Datei bearbeitet. Embarassed

Nun geht es! Danke! Smile

Außerdem: Kann eigentlich jemand erklären wie man scriptet, dass Tür 1 & 2 manuell und Tür 3 automatisch sind? Beim SD/D ist es ja nicht anders. Es sollte also nicht das Problem sein. Wink

Zudem stört mich, dass man die Türen ohne Haltestellenbremse öffnen kann.

Anzahl der Beiträge : 61 Anmeldedatum : 10.03.11

@sauter klappt reibungslos, danke!

Anzahl der Beiträge : 182 Anmeldedatum : 15.03.11

Bei mir steigen die fahgäste zwar ein, aber nic, ht mehr aus. weder wenn ich an der endstation bin, noch wenn ich auf betriebsfahrt umschildere Sad

Edit 1:
vielleicht kann das bei der lösung helfen: der Wagen hält knopf am dashboard leuchtet durchgehend, außer wenn die türen auf sind und immer wenn ich auf betriebsfahrt umschildere und dann keiner aussteigt erscheint Zugriffsverletzung

Anzahl der Beiträge : 1903 Anmeldedatum : 10.01.11

Bus2010 schrieb:: Bei mir steigen die fahgäste zwar ein, aber nic, ht mehr aus. weder wenn ich an der endstation bin, noch wenn ich auf betriebsfahrt umschildere
Edit 1:
vielleicht kann das bei der lösung helfen: der Wagen hält knopf am dashboard leuchtet durchgehend, außer wenn die türen auf sind und immer wenn ich auf betriebsfahrt umschildere und dann keiner aussteigt erscheint Zugriffsverletzung

Das die Lampe dauerhaft leuchtet ist klar. Wenn jemand, der aussteigen will, nicht aussteigen konnte, drückt der KI-Passagier sofort wieder den Haltewunsch. Das die Fahrgäste nicht bei einer "Betriebsfahrt" aussteigen kann auch an einem nicht definierten [all_exit] in der jeweiligen Hofdatei liegen.

Und das ist erst nach Veränderung des Scriptes aufgetreten? Eigentlich schwer vorstellbar.

Folgendes:
Stell das Originalscript wieder her und gib mal Rückmeldung.

savigny70 schrieb:: @sauter klappt reibungslos, danke!

Der Dank gebührt Janiboy genauso!

Bremerhaven-Bus-Fan schrieb:: Außerdem: Kann eigentlich jemand erklären wie man scriptet, dass Tür 1 & 2 manuell und Tür 3 automatisch sind? Beim SD/D ist es ja nicht anders. Es sollte also nicht das Problem sein.
Zudem stört mich, dass man die Türen ohne Haltestellenbremse öffnen kann.

Die Idee kam mir gestern auch.Ich habe in der kommenden Woche Vormittags immer etwas Zeit. Eventuell kümmere ich mich darum. Ich sagte aber bereits, dass ich bisher keine Ahnung vom scripten habe und mich dort erst einanrbeiten muss.

Sauter schrieb:

Bremerhaven-Bus-Fan schrieb:: Außerdem: Kann eigentlich jemand erklären wie man scriptet, dass Tür 1 & 2 manuell und Tür 3 automatisch sind? Beim SD/D ist es ja nicht anders. Es sollte also nicht das Problem sein.
Zudem stört mich, dass man die Türen ohne Haltestellenbremse öffnen kann.

Die Idee kam mir gestern auch.Ich habe in der kommenden Woche Vormittags immer etwas Zeit. Eventuell kümmere ich mich darum. Ich sagte aber bereits, dass ich bisher keine Ahnung vom scripten habe und mich dort erst einanrbeiten muss.

Schaut mal hier Wink

Ich hab das so übernommen und mit Sauters Macrowerten ersetzt. Türen gehen nur mit Hstbremse auf. 2 und 3 automatisch.

cooper schrieb:

Hallo,

da viele die Türen geändern haben möchten, hier das Scirpt dazu. Die Steuerung ist wie beim SD200 oder SD202. Außer die Türen vorn, können nicht getrennt von einander geöffnet werden.

Erste Tür: manuell
zweite Tür: Automatik
dritte Tür: Automatik

Fahrgäste steigen nur vorn ein!

Code:: '
##############
'Door Script
'##############

'Controls Doors

'(c) 2007-2009 Rüdiger Hülsmann
'(c) 2007-2009 Marcel Kuhnt

'Script Version: 1.1
'Omsi release: 1.0

'Needs:
'- elec

'Revision History:
'- Marcel Kuhnt    13.06.2009 Batterietrennschalter => elec_busbar_main
'- Marcel Kuhnt    21.06.2009 AI-Unterstützung hinzugefügt
'- Rüdiger Hülsmann 24.10.2009 Ansteuerung des Kinderwagenwunsches modifiziert
'- Rüdiger Hülsmann 19.12.2009 Timer für Ausstiegstür jetzt Timegap-basiert, Bugfix: Tür schließt jetzt nur bei elec_busbar=1
'- RÜdiger Hülsmann 22.09.2010 Door light trigger value set to 0.1
'- RÜdiger Hülsmann 07.11.2010 Door speed based on reservoir pressure, air-operated doors made an option
'- Marcel Kuhnt    08.11.2010 AI procedure closing doors debugged
'- Rüdiger Hülsmann 21.11.2010 Front doors only operable when busbar on
'- Rüdiger Hülsmann 23.12.2010 External front door operation included, option: doors only operable with actual stop brake
'- Rüdiger Hülsmann 31.12.2010 Electric door function debugged
'- Rüdiger Hülsmann 05.01.2011 20h-switch
'- Rüdiger Hülsmann 07.01.2011 Backdoor manual switch sound debugged, 20h switch depending on bus type
'- Rüdiger Hülsmann 19.01.2011 Electric door support

'--------------------------------------------------------------------------------

{trigger:bus_doorfront0}
(L.L.elec_busbar_main) (L.L.bremse_halte_sw) (C.L.door_needs_stopbrake) ! && &&
(L.L.elec_busbar_main) (L.L.bremse_halte) (C.L.door_needs_stopbrake) && && ||
{if}
   (M.L.trg_bus_doorfront0)
{endif}
1 (S.L.cockpit_tuertaster1)
{end}

{trigger:bus_doorfront0_off}
0 (S.L.cockpit_tuertaster1)
{end}

{trigger:bus_doorfront0_external}
(L.L.elec_busbar_avail)
{if}
   (M.L.trg_bus_doorfront0)
{endif}
{end}

{trigger:bus_doorback1}
(L.L.elec_busbar_main) (L.L.bremse_halte_sw) (C.L.door_needs_stopbrake) ! && &&
(L.L.elec_busbar_main) (L.L.bremse_halte) (C.L.door_needs_stopbrake) && && ||
{if}
   (M.L.trg_bus_doorback1)
{endif}
1 (S.L.cockpit_tuertaster2)
{end}

{trigger:bus_doorback1_off}
0 (S.L.cockpit_tuertaster2)
{end}

{trigger:bus_doorback2}
(L.L.elec_busbar_main) (L.L.bremse_halte_sw) (C.L.door_needs_stopbrake) ! && &&
(L.L.elec_busbar_main) (L.L.bremse_halte) (C.L.door_needs_stopbrake) && && ||
{if}
   (M.L.trg_bus_doorback2)
{endif}
1 (S.L.cockpit_tuertaster3)
{end}

{trigger:bus_doorback2_off}
0 (S.L.cockpit_tuertaster3)

{trigger:bus_dooraft}
(M.L.trg_bus_dooraft)
{end}

{trigger:bus_20h-switch}
(C.L.cockpit_has_20h_switch)
{if}
   (M.L.trg_bus_20h-switch)
{endif}
{end}

{trigger:int_haltewunsch}
1 (S.L.haltewunsch)
{end}

{trigger:door_haltewunsch}
1 (S.L.haltewunsch) (S.L.door_haltewunsch_knopfdruck)
{end}

{trigger:door_haltewunsch_off}
0 (S.L.door_haltewunsch_knopfdruck)
{end}

{trigger:cp_schalter_kinderwagen}
(L.L.door_handsteuerung) ! (S.L.door_handsteuerung)
{if}
   0 (S.L.door_kinderwagenwunsch)
   (T.L.ev_kippschalter_ein)
{else}
   (T.L.ev_kippschalter_aus)
{endif}

{end}

{trigger:door_kinderwagenwunsch}
(L.L.bremse_halte) (L.L.door_handsteuerung) ! &&
{if}
   1 (S.L.door_kinderwagenwunsch)
{endif}
{end}

{macro:Door_Init}
1000 random 500 / 1 - (C.L.door_acc_var) * (C.L.fdoor_acc) + (S.L.doorAcc_0)
1000 random 500 / 1 - (C.L.door_acc_var) * (C.L.fdoor_acc) + (S.L.doorAcc_1)
1000 random 500 / 1 - (C.L.door_acc_var) * (C.L.bdoor_acc) + (S.L.doorAcc_2)
1000 random 500 / 1 - (C.L.door_acc_var) * (C.L.bdoor_acc) + (S.L.doorAcc_3)

1000 random 500 / 1 - (C.L.door_maxspeed_var) * (C.L.fdoor_maxspeed) + (S.L.doorMaxSpeed_0_norm)
1000 random 500 / 1 - (C.L.door_maxspeed_var) * (C.L.fdoor_maxspeed) + (S.L.doorMaxSpeed_1_norm)
1000 random 500 / 1 - (C.L.door_maxspeed_var) * (C.L.bdoor_maxspeed) + (S.L.doorMaxSpeed_2_norm)
1000 random 500 / 1 - (C.L.door_maxspeed_var) * (C.L.bdoor_maxspeed) + (S.L.doorMaxSpeed_3_norm)

(C.L.door_refl) (S.L.doorRefl_0)
(C.L.door_refl) (S.L.doorRefl_1)
(C.L.door_refl) (S.L.doorRefl_2)
(C.L.door_refl) (S.L.doorRefl_3)

{end}

{macro:Door_Frame}
(M.L.Door0_Calc)
(M.L.Door1_Calc)
(M.L.DoorAftCalc)
(M.L.Door2_Calc)
(M.L.Door3_Calc)

(L.L.door_0) 0.9 > (S.L.PAX_Entry0_Open)
(L.L.door_1) 0.9 > (S.L.PAX_Exit0_Open)
(L.L.door_2) 0.9 > (L.L.door_2) 0.9 > && (S.L.PAX_Exit1_Open)

' "Dauerfeuer"-Haltewunsch über Kinderwagenschalter (macht genau dasselbe wie der "trigger:int_haltewunsch"):
(L.L.door_handsteuerung) (L.L.door_haltewunsch_knopfdruck) ||
{if}
   1 (S.L.haltewunsch)
{endif}

' Setzen der Haltestellenbremse erst bei Stillstand des Busses:
(L.L.bremse_halte_sw) (L.L.door_20h_sw) ||
(L.L.bremse_halte) ! (L.L.Velocity) (C.L.Door_Bremse_Halte_MaxKMH) < && &&
{if}
   (L.L.elec_busbar_main)
   {if}
      (T.L.ev_haltebremse_an)
      1 (S.L.bremse_halte)
   {endif}
{endif}

' Anhand dieser Bedingungen kann nun die Automatiktür geöffnet werden:
(M.L.DoorAft_Open)

' Türfreigabekriterium

(L.L.bremse_halte_sw) (L.L.bremse_halte) && (S.L.door_freigabe)

' Haltewunschlampe:
(L.L.haltewunsch) (L.L.door_1) 0.2 < (L.L.elec_busbar_main) && &&
(L.L.haltewunsch) (L.L.door_2) 0.2 < (L.L.elec_busbar_main) && &&
{if}
   1 (S.L.haltewunschlampe)
{else}
   0 (S.L.haltewunschlampe) (S.L.haltewunsch)
{endif}

' Abfall des Kinderwagenwunsch-Relais bei fehlender Stromversorgung:

(L.L.elec_busbar_main) 0 =
{if}
   0 (S.L.door_kinderwagenwunsch)
{endif}

' Beleuchtung der Einstiege

(L.L.elec_busbar_main)
{if}
   (L.L.door_0) 0.1 > (L.L.door_0) 0.1 > || (S.L.door_light_1)
   (L.L.door_1) 0.1 > (L.L.door_1) 0.1 > || (S.L.door_light_2)
   (L.L.door_2) 0.1 > (L.L.door_2) 0.1 > || (S.L.door_light_3)
{else}
   0 (S.L.door_light_1) (S.L.door_light_2) (S.L.door_light_3)
{endif}

' Druckabhängige Türgeschwindigkeit

(C.L.door_druckluft)
{if}
   (L.L.doorMaxSpeed_0_norm) (L.L.bremse_p_Tank04) 100000 - 850000 / (S.L.doorMaxSpeed_0)
   (L.L.doorMaxSpeed_1_norm) (L.L.bremse_p_Tank04) 100000 - 850000 / (S.L.doorMaxSpeed_1)
   (L.L.doorMaxSpeed_2_norm) (L.L.bremse_p_Tank04) 100000 - 850000 / (S.L.doorMaxSpeed_2)
   (L.L.doorMaxSpeed_3_norm) (L.L.bremse_p_Tank04) 100000 - 850000 / (S.L.doorMaxSpeed_3)
{endif}
'----------------------
' AI-Ablauf:

(L.L.AI_Scheduled_AtStation) s0
1 =
{if}
'Wenn Türen geöffnet werden sollen:
(L.L.Velocity) (C.L.Door_Bremse_Halte_MaxKMH) <
{if}
'Nur, wenn v < maxkmh, sonst warten
'Taster jeweils nur betätigen, falls noch nicht an
   (L.L.bremse_halte_sw) !
   {if}
      (M.L.trg_bus_dooraft)
   {endif}
   (L.L.doorTarget_0) ! (L.L.door_AI_timer) 0.3 > &&
   {if}
      (M.L.trg_bus_doorfront0)
   {endif}
   (L.L.doorTarget_1) ! (L.L.door_AI_timer) 0.6 > &&
   {if}
      (M.L.trg_bus_doorback1)
   {endif}
   (L.L.doorTarget_2) ! (L.L.door_AI_timer) 0.6 > &&
   {if}
      (M.L.trg_bus_doorback2)
   {endif}
{else}
   0 (S.L.door_AI_timer)
{endif}
(L.L.door_AI_timer) (L.S.Timegap) + (S.L.door_AI_timer)
{else}
l0 -1 =
{if}
'Wenn Türen geschlossen werden sollen:
'Taster jeweils nur betätigen, falls noch nicht aus:
(L.L.doorTarget_1)
{if}
   (M.L.trg_bus_doorback1)
   0 (S.L.door_AI_timer)
{endif}
(L.L.doorTarget_0) (L.L.door_AI_timer) 0.3 > &&
{if}
   (M.L.trg_bus_doorfront0)
{endif}
(L.L.doorTarget_2) (L.L.door_AI_timer) 0.3 > &&
{if}
   (M.L.trg_bus_doorback2)
   0 (S.L.door_AI_timer)
{endif}
'Haltestellenbremse erst wegnehmen, wenn alle Türen zu. Dann auch erst den Bus AI-mäßig freigeben:
(L.L.door_0) 0.1 <
(L.L.door_1) 0.1 < &&
(L.L.door_2) 0.1 < &&
{if}
   (L.L.bremse_halte_sw) (L.L.door_AI_timer) 0.3 > &&
   {if}
      (M.L.trg_bus_dooraft)
   {endif}
   (L.L.bremse_halte_sw) !
   {if}
      0 (S.L.AI_Scheduled_AtStation)
   {endif}
{else}
'Sollte eine der Türen auf sein und die Haltestellenbremse aus, dann sofort diese einlegen
   (L.L.bremse_halte_sw) !
   {if}
      (M.L.trg_bus_dooraft)
   {endif}
   (L.L.doorTarget_0) !
   (L.L.doorTarget_1) ! &&
   (L.L.doorTarget_2) ! &&
   {if}
      0 (S.L.door_AI_timer)
   {endif}
{endif}
(L.L.door_AI_timer) (L.S.Timegap) + (S.L.door_AI_timer)
{endif}
{endif}

{end}

{macro:Door0_Calc}
(C.L.electric_doors)
{if}
   (L.L.doorTarget_0)
   {if}
      (L.L.door_0) (F.L.door_0_opn_speed) (S.L.doorMaxSpeed_0)
   {else}
      (L.L.door_0) (F.L.door_0_cls_speed) (S.L.doorMaxSpeed_0)
   {endif}

   (C.L.fdoor_acc) (S.L.doorAcc_0)

   (L.L.doorTarget_0) ! (L.L.doorSpeed_0) s0 abs 0.05 > (L.L.door_0) 0 > || &&
   {if}
      l0 /-/ (L.L.doorMaxSpeed_0) <
      {if}
         (L.L.doorSpeed_0) (L.L.doorAcc_0) (L.S.Timegap) * - (S.L.doorSpeed_0)
      {else}
         (L.L.doorSpeed_0) (L.L.doorAcc_0) (L.S.Timegap) * + (S.L.doorSpeed_0)
      {endif}
      (L.L.door_0) (L.L.doorSpeed_0) (L.S.Timegap) * + (S.L.door_0)
   {else}
      (L.L.doorSpeed_0) abs 0.05 > (L.L.door_0) 1 < || (L.L.doorTarget_0) &&
      {if}
         l0 (L.L.doorMaxSpeed_0) <
         {if}
            (L.L.doorSpeed_0) (L.L.doorAcc_0) (L.S.Timegap) * + (S.L.doorSpeed_0)
         {else}
            (L.L.doorSpeed_0) (L.L.doorAcc_0) (L.S.Timegap) * - (S.L.doorSpeed_0)
         {endif}
         (L.L.door_0) (L.L.doorSpeed_0) (L.S.Timegap) * + (S.L.door_0)
      {else}
         0 (S.L.doorSpeed_0)
      {endif}
   {endif}
{else}
   (L.L.doorTarget_0) ! (L.L.doorSpeed_0) s0 abs 0.05 > (L.L.door_0) 0 > || &&
   {if}
      l0 /-/ (L.L.doorMaxSpeed_0) <
      {if}
         (L.L.doorSpeed_0) (L.L.doorAcc_0) (L.S.Timegap) * - (S.L.doorSpeed_0)
      {endif}
      (L.L.door_0) (L.L.doorSpeed_0) (L.S.Timegap) * + (S.L.door_0)
   {else}
      (L.L.doorSpeed_0) abs 0.05 > (L.L.door_0) 1 < || (L.L.doorTarget_0) &&
      {if}
         l0 (L.L.doorMaxSpeed_0) <
         {if}
            (L.L.doorSpeed_0) (L.L.doorAcc_0) (L.S.Timegap) * + (S.L.doorSpeed_0)
         {endif}
         (L.L.door_0) (L.L.doorSpeed_0) (L.S.Timegap) * + (S.L.door_0)
      {else}
         0 (S.L.doorSpeed_0)
      {endif}
   {endif}
{endif}

(L.L.door_0) 1 >
{if}
   (T.L.ev_doorhitopen_0)
   1 (S.L.door_0)
   (L.L.doorSpeed_0) /-/ (L.L.doorRefl_0) * (S.L.doorSpeed_0)
{else}
   (L.L.door_0) 0 <
   {if}
      (T.L.ev_doorhitclose_0)
      0 (S.L.door_0)
      (L.L.doorSpeed_0) /-/ (L.L.doorRefl_0) * (S.L.doorSpeed_0)
   {endif}
{endif}
{end}

{macro:Door1_Calc}
(C.L.electric_doors)
{if}
   (L.L.doorTarget_1)
   {if}
      (L.L.door_1) (F.L.door_1_opn_speed) (S.L.doorMaxSpeed_1)
   {else}
      (L.L.door_1) (F.L.door_1_cls_speed) (S.L.doorMaxSpeed_1)
   {endif}

   (C.L.fdoor_acc) (S.L.doorAcc_1)

   (L.L.doorTarget_1) ! (L.L.doorSpeed_1) s0 abs 0.05 > (L.L.door_1) 0 > || &&
   {if}
      l0 /-/ (L.L.doorMaxSpeed_1) <
      {if}
         (L.L.doorSpeed_1) (L.L.doorAcc_1) (L.S.Timegap) * - (S.L.doorSpeed_1)
      {else}
         (L.L.doorSpeed_1) (L.L.doorAcc_1) (L.S.Timegap) * + (S.L.doorSpeed_1)
      {endif}
      (L.L.door_1) (L.L.doorSpeed_1) (L.S.Timegap) * + (S.L.door_1)
   {else}
      (L.L.doorSpeed_1) abs 0.05 > (L.L.door_1) 1 < || (L.L.doorTarget_1) &&
      {if}
         l0 (L.L.doorMaxSpeed_1) <
         {if}
            (L.L.doorSpeed_1) (L.L.doorAcc_1) (L.S.Timegap) * + (S.L.doorSpeed_1)
         {else}
            (L.L.doorSpeed_1) (L.L.doorAcc_1) (L.S.Timegap) * - (S.L.doorSpeed_1)
         {endif}
         (L.L.door_1) (L.L.doorSpeed_1) (L.S.Timegap) * + (S.L.door_1)
      {else}
         0 (S.L.doorSpeed_1)
      {endif}
   {endif}
{else}
   (L.L.doorTarget_1) ! (L.L.doorSpeed_1) s0 abs 0.05 > (L.L.door_1) 0 > || &&
   {if}
      l0 /-/ (L.L.doorMaxSpeed_1) <
      {if}
         (L.L.doorSpeed_1) (L.L.doorAcc_1) (L.S.Timegap) * - (S.L.doorSpeed_1)
      {endif}
      (L.L.door_1) (L.L.doorSpeed_1) (L.S.Timegap) * + (S.L.door_1)
   {else}
      (L.L.doorSpeed_1) abs 0.05 > (L.L.door_1) 1 < || (L.L.doorTarget_1) &&
      {if}
         l0 (L.L.doorMaxSpeed_1) <
         {if}
            (L.L.doorSpeed_1) (L.L.doorAcc_1) (L.S.Timegap) * + (S.L.doorSpeed_1)
         {endif}
         (L.L.door_1) (L.L.doorSpeed_1) (L.S.Timegap) * + (S.L.door_1)
      {else}
         0 (S.L.doorSpeed_1)
      {endif}
   {endif}
{endif}
(L.L.door_1) 1 >
{if}
   (T.L.ev_doorhitopen_1)
   1 (S.L.door_1)
   (L.L.doorSpeed_1) /-/ (L.L.doorRefl_1) * (S.L.doorSpeed_1)
{else}
   (L.L.door_1) 0 <
   {if}
      (T.L.ev_doorhitclose_1)
      0 (S.L.door_1)
      (L.L.doorSpeed_1) /-/ (L.L.doorRefl_1) * (S.L.doorSpeed_1)
   {endif}
{endif}
{end}

{macro:DoorAft_Open}

(L.L.haltewunsch) (L.L.bremse_halte) &&
{if}
   (L.L.doorTarget_1) !
   (L.L.doorTarget_2) !
   (L.L.bremse_halte_sw) &&
   {if}
      (T.L.ev_doortriggeropen_2)
      1 (S.L.doorTarget_1)
      1 (S.L.doorTarget_2)
      (C.L.door_druckluft)
      {if}
      (L.L.bremse_p_Tank04) 100000 - 0.96 * 100000 + (S.L.bremse_p_Tank04)
      {endif}
   {endif}
   0 (S.L.doorAftLastOpen)
{endif}
{end}

{macro:DoorAftCalc}

(L.L.bremse_halte_sw) !
(L.L.door_20h_sw) ! &&
(L.L.door_2) 0 = &&
(L.L.door_3) 0 = &&
(L.L.elec_busbar_main) ! ||
(L.L.bremse_halte) &&
{if}
   0 (S.L.bremse_halte) (S.L.doorAftLastOpen)
   (T.L.ev_haltebremse_aus)
{endif}

(L.L.elec_busbar_main)
{if}
   (L.L.bremse_halte)
   {if}
      (L.L.doorAftLastOpen) (L.S.Timegap) + (S.L.doorAftLastOpen)
   {endif}

   (L.L.doorTarget_1)
   (L.L.doorAftLastOpen) (C.L.doorAftOpenTime) > &&
   {if}
      (T.L.ev_doortriggerclose_2)
      0 (S.L.doorTarget_1)
      (C.L.door_druckluft)
      {if}
      (L.L.bremse_p_Tank04) 100000 - 0.96 * 100000 + (S.L.bremse_p_Tank04)
      {endif}
   {endif}

   (L.L.doorTarget_2)
   (L.L.doorAftLastOpen) (C.L.doorAftOpenTime) > &&
   {if}
      (T.L.ev_doortriggerclose_2)
      0 (S.L.doorTarget_2)
      (C.L.door_druckluft)
      {if}
      (L.L.bremse_p_Tank04) 100000 - 0.96 * 100000 + (S.L.bremse_p_Tank04)
      {endif}
   {endif}
{endif}
{end}

{macro:Door2_Calc}
(C.L.electric_doors)
{if}
   (L.L.doorTarget_1)
   {if}
      (L.L.door_2) (F.L.door_2_opn_speed) (S.L.doorMaxSpeed_2)
   {else}
      (L.L.door_2) (F.L.door_2_cls_speed) (S.L.doorMaxSpeed_2)
   {endif}

   (C.L.bdoor_acc) (S.L.doorAcc_2)

   (L.L.doorTarget_1) ! (L.L.doorSpeed_2) s0 abs 0.05 > (L.L.door_2) 0 > || &&
   {if}
      l0 /-/ (L.L.doorMaxSpeed_2) <
      {if}
         (L.L.doorSpeed_2) (L.L.doorAcc_2) (L.S.Timegap) * - (S.L.doorSpeed_2)
      {else}
         (L.L.doorSpeed_2) (L.L.doorAcc_2) (L.S.Timegap) * + (S.L.doorSpeed_2)
      {endif}
      (L.L.door_2) (L.L.doorSpeed_2) (L.S.Timegap) * + (S.L.door_2)
   {else}
      (L.L.doorSpeed_2) abs 0.05 > (L.L.door_2) 1 < || (L.L.doorTarget_1) &&
      {if}
         l0 (L.L.doorMaxSpeed_2) <
         {if}
            (L.L.doorSpeed_2) (L.L.doorAcc_2) (L.S.Timegap) * + (S.L.doorSpeed_2)
         {else}
            (L.L.doorSpeed_2) (L.L.doorAcc_2) (L.S.Timegap) * - (S.L.doorSpeed_2)
         {endif}
         (L.L.door_2) (L.L.doorSpeed_2) (L.S.Timegap) * + (S.L.door_2)
      {else}
         0 (S.L.doorSpeed_2)
      {endif}
   {endif}
{else}
   (L.L.doorTarget_1) ! (L.L.doorSpeed_2) s0 abs 0.05 > (L.L.door_2) 0 > || &&
   {if}
      l0 /-/ (L.L.doorMaxSpeed_2) <
      {if}
         (L.L.doorSpeed_2) (L.L.doorAcc_2) (L.S.Timegap) * - (S.L.doorSpeed_2)
      {endif}
      (L.L.door_2) (L.L.doorSpeed_2) (L.S.Timegap) * + (S.L.door_2)
   {else}
      (L.L.doorSpeed_2) abs 0.05 > (L.L.door_2) 1 < || (L.L.doorTarget_1) &&
      {if}
         l0 (L.L.doorMaxSpeed_2) <
         {if}
            (L.L.doorSpeed_2) (L.L.doorAcc_2) (L.S.Timegap) * + (S.L.doorSpeed_2)
         {endif}
         (L.L.door_2) (L.L.doorSpeed_2) (L.S.Timegap) * + (S.L.door_2)
      {else}
         0 (S.L.doorSpeed_2)
      {endif}
   {endif}
{endif}

(L.L.door_2) 1 >
{if}
   (T.L.ev_doorhitopen_2)
   1 (S.L.door_2)
   (L.L.doorSpeed_2) /-/ (L.L.doorRefl_2) * (S.L.doorSpeed_2)
{else}
   (L.L.door_2) 0 <
   {if}
      (T.L.ev_doorhitclose_2)
      0 (S.L.door_2)
      (L.L.doorSpeed_2) /-/ (L.L.doorRefl_2) * (S.L.doorSpeed_2)
   {endif}
{endif}
{end}

{macro:Door3_Calc}
(C.L.electric_doors)
{if}
   (L.L.doorTarget_2)
   {if}
      (L.L.door_3) (F.L.door_3_opn_speed) (S.L.doorMaxSpeed_3)
   {else}
      (L.L.door_3) (F.L.door_3_cls_speed) (S.L.doorMaxSpeed_3)
   {endif}

   (C.L.bdoor_acc) (S.L.doorAcc_3)

   (L.L.doorTarget_2) ! (L.L.doorSpeed_3) s0 abs 0.05 > (L.L.door_3) 0 > || &&
   {if}
      l0 /-/ (L.L.doorMaxSpeed_3) <
      {if}
         (L.L.doorSpeed_3) (L.L.doorAcc_3) (L.S.Timegap) * - (S.L.doorSpeed_3)
      {else}
         (L.L.doorSpeed_3) (L.L.doorAcc_3) (L.S.Timegap) * + (S.L.doorSpeed_3)
      {endif}
      (L.L.door_3) (L.L.doorSpeed_3) (L.S.Timegap) * + (S.L.door_3)
   {else}
      (L.L.doorSpeed_3) abs 0.05 > (L.L.door_3) 1 < || (L.L.doorTarget_2) &&
      {if}
         l0 (L.L.doorMaxSpeed_3) <
         {if}
            (L.L.doorSpeed_3) (L.L.doorAcc_3) (L.S.Timegap) * + (S.L.doorSpeed_3)
         {else}
            (L.L.doorSpeed_3) (L.L.doorAcc_3) (L.S.Timegap) * - (S.L.doorSpeed_3)
         {endif}
         (L.L.door_3) (L.L.doorSpeed_3) (L.S.Timegap) * + (S.L.door_3)
      {else}
         0 (S.L.doorSpeed_3)
      {endif}
   {endif}
{else}
   (L.L.doorTarget_2) ! (L.L.doorSpeed_3) s0 abs 0.05 > (L.L.door_3) 0 > || &&
   {if}
      l0 /-/ (L.L.doorMaxSpeed_3) <
      {if}
         (L.L.doorSpeed_3) (L.L.doorAcc_3) (L.S.Timegap) * - (S.L.doorSpeed_3)
      {endif}
      (L.L.door_3) (L.L.doorSpeed_3) (L.S.Timegap) * + (S.L.door_3)
   {else}
      (L.L.doorSpeed_3) abs 0.05 > (L.L.door_3) 1 < || (L.L.doorTarget_2) &&
      {if}
         l0 (L.L.doorMaxSpeed_3) <
         {if}
            (L.L.doorSpeed_3) (L.L.doorAcc_3) (L.S.Timegap) * + (S.L.doorSpeed_3)
         {endif}
         (L.L.door_3) (L.L.doorSpeed_3) (L.S.Timegap) * + (S.L.door_3)
      {else}
         0 (S.L.doorSpeed_3)
      {endif}
   {endif}
{endif}

(L.L.door_3) 1 >
{if}
   (T.L.ev_doorhitopen_3)
   1 (S.L.door_3)
   (L.L.doorSpeed_3) /-/ (L.L.doorRefl_3) * (S.L.doorSpeed_3)
{else}
   (L.L.door_3) 0 <
   {if}
      (T.L.ev_doorhitclose_3)
      0 (S.L.door_3)
      (L.L.doorSpeed_3) /-/ (L.L.doorRefl_3) * (S.L.doorSpeed_3)
   {endif}
{endif}

{end}

{macro:trg_bus_doorfront0}

(L.L.doorTarget_0) ! (S.L.doorTarget_0)
{if}
   (T.L.ev_doortriggeropen_0)
{else}
   (T.L.ev_doortriggerclose_0)
{endif}
   (C.L.door_druckluft)
   {if}
   (L.L.bremse_p_Tank04) 100000 - 0.98 * 100000 + (S.L.bremse_p_Tank04)
   {endif}
{end}

{macro:trg_bus_doorback1}

(L.L.doorTarget_1) ! (S.L.doorTarget_1)
{if}
   (T.L.ev_doortriggeropen_1)
{else}
   (T.L.ev_doortriggerclose_1)
{endif}
   (C.L.door_druckluft)
   {if}
   (L.L.bremse_p_Tank04) 100000 - 0.98 * 100000 + (S.L.bremse_p_Tank04)
   {endif}
{end}

{macro:trg_bus_doorback2}

(L.L.doorTarget_2) ! (S.L.doorTarget_2)
{if}
   (T.L.ev_doortriggeropen_2)
{else}
   (T.L.ev_doortriggerclose_2)
{endif}
   (C.L.door_druckluft)
   {if}
   (L.L.bremse_p_Tank04) 100000 - 0.98 * 100000 + (S.L.bremse_p_Tank04)
   {endif}
{end}

{macro:trg_bus_dooraft}
(L.L.bremse_halte_sw) ! (S.L.bremse_halte_sw)

(L.L.bremse_halte_sw)
{if}
   (T.L.ev_haltebremse_sw_an)
{else}
   (T.L.ev_haltebremse_sw_aus)
{endif}
{end}

{macro:trg_bus_20h-switch}
(L.L.door_20h_sw) ! (S.L.door_20h_sw)

(L.L.door_20h_sw)
{if}
   (T.L.ev_haltebremse_sw_an)
{else}
   (T.L.ev_haltebremse_sw_aus)
{endif}
{end}

Um den Code einzufügen, ist die Datei doordar.osc zu ändern.

Des Weiteren in der Datei door_varlist.txt muss aus doorTarget_23 in doorTarget_2 geändern werden.

cooper

Anzahl der Beiträge : 182 Anmeldedatum : 15.03.11

Also, das Script in der doordar.osc ist okay. aber probleme macht die aänderung der passegercabin_d92.cfg. wenn ich das originalscript wiederherstelle, geht alles ohne probleme(außer dass die fahrgäste immer hinten einsteigen wollen). wenn ich doordar.osc und passengercabin_d92.cfg wie beschrieben ändere,kommt der oben genannte fehler. wenn ich die doordar.osc wie beschrieben ändere aber die passengercabin_d92.cfg nicht, get alles, aber die fahrgäste steigen wieder hinten ein. deshalb glaube ich dass in der passengercabin_d92.cfg irgendetwas nicht stimmt, werde es nochmal prüfen

Edit1: Hier mal die passengercabin_d92.cfg aus C:\m-r-software\Omsi\Vehicles\Mercedes\Model:

Code:: [passpos] erstellt neue Passenger-Position
x
y
z    x,y,z-Koordinaten des Attachpunktes "Arsch" bzw. "Fuß"
h    Sitzhöhe über Boden (0 = Stehplatz)
rot    Drehung um z-Achse (Grad, 0 = Fahrtrichtung)

[drivpos] erstellt eine neue Fahrer-Position
x
y
z    x,y,z-Koordinaten des Attachpunktes "Arsch" bzw. "Fuß"
h    Sitzhöhe über Boden (0 = Stehplatz)
rot    Drehung um z-Achse (Grad, 0 = Fahrtrichtung)

[entry]    definiert Eingang
num    Nr. des Pathpoints, welcher Eingang sein soll. Es können
      mittels mehrerer [Entry]-Befehle mehrere Eingänge definiert
      werden.

[exit]
num    analog für Ausgang

[stamper] definiert, an welchem Pfadpunkt ein Entwerter angebracht ist
num    Nr. des Pathpoints
x
y
z    Position des Entwerterschlitzes oder des Punktes, wohin die Fahrkarte geführt werden soll

[ticket_sale]
num    Pfadpunkt
x    Position der Ticketausgabe
y
z

[ticket_sale_money_point]
pos_x    Position der Geldabgabe
pos_y
pos_z
var_x    Variation der Koordinaten
var_y

[ticket_sale_change_point]
pos_x    Position der Geldrückgabe
pos_y
pos_z
var_x    Variation der Koordinaten
var_y

###################################
[entry]
1

{noticketsale}

[entry]
1

{noticketsale}

[entry]
1

[exit]
34

[exit]
28

###################################

[stamper]
11
0.0
-0.554
0.505

[ticket_sale]
2
-0.500
4.850
1.096

[ticket_sale_money_point]
-0.400
4.750
1.096
0.06
0.1

[ticket_sale_change_point]
-0.380
4.680
1.096
0.03
0.03

###################################

Fahrersitz:

[drivpos]
-0.733
4.329
0.976
0.4
0

###################################

Sitze

###################################
3er-Bank
###################################

Sitze

[passpos]
-0.853
3.313
0.976
0.50
0

[passpos]
0.755
3.317
0.969
0.50
0

[passpos]
0.908
2.274
0.636
0.90
180

[passpos]
0.513
2.274
0.636
0.50
180

[passpos]
-0.548
2.281
0.636
0.50
180

[passpos]
-0.961
2.281
0.636
0.50
180

[passpos]
-0.972
1.210
0.636
0.50
0

[passpos]
-0.542
1.210
0.636
0.50
0

[passpos]
0.533
1.210
0.636
0.50
0

[passpos]
0.967
1.210
0.636
0.50
0

[passpos]
0.954
-0.977
0.820
0.50
0

[passpos]
0.538
-0.977
0.820
0.50
0

[passpos]
-0.524
-0.989
0.818
0.50
0

[passpos]
-0.956
-0.989
0.818
0.50
0

[passpos]
-0.969
-1.687
0.813
0.50
0

[passpos]
0.518
-1.687
0.813
0.50
0

[passpos]
0.521
-1.687
0.813
0.50
0

[passpos]
0.973
-1.687
0.813
0.50
0

[passpos]
0.958
-2.427
0.985
0.50
0

[passpos]
0.532
-2.427
0.985
0.50
0

[passpos]
-0.533
-2.427
0.985
0.50
0

[passpos]
-0.954
-2.427
0.986
0.50
0

[passpos]
-0.967
-2.817
1.118
0.50
180

[passpos]
-0.544
-2.817
1.118
0.50
180

[passpos]
0.517
-2.817
1.118
0.50
180

[passpos]
0.970
-2.817
1.118
0.50
180

[passpos]
-0.968
-3.905
1.118
0.50
0

[passpos]
-0.560
-3.905
1.118
0.50
0

[passpos]
-0.961
-4.536
1.118
0.50
0

[passpos]
-0.534
-4.536
1.118
0.50
0

[passpos]
-0.838
-5.446
1.156
0.50
0

[passpos]
-0.398
-5.446
1.156
0.50
0

[passpos]
0.037
-5.446
1.156
0.50
0

[passpos]
0.461
-5.446
1.156
0.50
0

[passpos]
-0.600
-0.645
0.288
0
90

[passpos]
-0.600
0.266
0.288
0
90

[passpos]
-0.600
0.207
0.288
0
90

[passpos]
-0.948
-0.220
0.288
0
90

[passpos]
-0.948
0.238
0.288
0
90

[passpos]
-0.948
0.671
0.288
0
90

Anzahl der Beiträge : 153 Anmeldedatum : 19.02.11 Alter : 28 Ort : Bremerhaven

@Sauter: Wäre echt toll, wenn du dich da ran setzt!

@Deli: Weißt du wie man es ändert, dass nur Tür 3 automatisch ist, und Tür 2 manuell? So ist es, zumindest bei uns, in der Realität! Edit: Außerdem funktioniert das Script bei mir nicht! ("###########################" ist ein ungültiger Gleichkommawert." [oder so] + Zugriffsverletzung)

Anzahl der Beiträge : 40 Anmeldedatum : 06.08.11

Hallo,

@ Bremerhaven-Bus-Fan :

Geht mir genauso. OMSI lässt sich nur über task Manager beenden ...

Und sonst steigen die Leute zwar nur vorne ein, jedoch nicht vorne aus. Sie stellen
sich in die erste Tür und auch wen diese offen ist geht keiner raus.

Ansonsten finde ich es ganz gut. Ich fände klasse, wenn ihr das mit den Personen
und die Türen hinbekommt. Mir ist es dabei egal, wo die Leute einsteigen, nur sie dürfen
nicht erst nach hinten laufen.
Zu den Türen ist es okay, wenn 1+2 manuell sind und die dritte via Haltestellenbremse
automatisiert ist.

MfG
MB_Citaro_E_4

Anzahl der Beiträge : 39 Anmeldedatum : 27.11.09 Alter : 27 Ort : Bennigsen

Habe auch das problem mit der Zugriffsverletung.

Bei mir geht überhaupt die dritte Türe nicht auf! Man hört nur den Türsound

» Fahrgäste hinten einsteigen
» Türmod Problem der Ki [vermutlich gelöst]
» Mercedes O405N2 OBI
» Mercedes-Benz O405N2
» Mercedes O405N2 only get in in the front....